[goggy]

Zitat:Original geschrieben von Rumgucker
...
Bleibt aber vermutlich eine Illusion. Jedenfalls glaube ich nicht, dass das ferne g3 (es kommt ja noch nach g2) diese Zauberei bewirken kann - es geht schließlich um eine gegenüber dem Svetlana-Datenblatt 70-fache Klirrminderung. Nenene... das ist Bauernfängerei.
...

Die 0,05% Klirr könnten schon hinkommen. Die im Svetlana-DB genannten 3,5% beziehen sich auf 250V und 39V Ausgangspegel. Mit 250V und 1V Ausgang (zum Beispiel) ist der Klirr natürlich geringer.
Bei den Spice-Modellen von Pentoden ist g3 i.d.R. fest mit der Kathode verbunden. Es gibt aber auch Modelle für Triodenbeschaltung, da sollte g3 dann mit der Anode verbunden sein.
Für die Spice-Experten, hier das Modell der russischen Gegentype zur EF86 als Triode geschaltet (ich hab leider zu wenig Ahnung davon und kann das nicht prüfen):

.SUBCKT 6J32P_T 1 2 3 ; P G C (Triode) 29-Oct-2006
+ PARAMS: MU= 37.23 EX= 1.264 KG1=1276.2 KP=231.21
+ KVB= 300.0 VCT= 0.00 RGI=1000
+ CCG=4P CGP=0.1P CCP=5.5P
E1 7 0 VALUE=
+{V(1,3)/KP*LN(1+EXP(KP*(1/MU+(V(2,3)+VCT)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG} ; CATHODE-GRID;
C2 2 1 {CGP} ; GRID-PLATE;
C3 1 3 {CCP} ; CATHODE-PLATE;
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

Und das Pentoden-Modell:

.SUBCKT 6J32P 1 2 3 4 ; P G1 C G2 (Pentode) 19-Dec-2006
+ PARAMS: MU= 37.72 EX= 1.526 KG1=3140 KP=120 KC= 813
+ KVB= 8.7 VCT= 0.00 RGI=1k
+ CCG=4P CPG1=0.05P CCP=5.5P
RE1 7 0 1MEG
E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(4,3)/KP*LN(1+EXP((1/MU+V(2,3)/V(4,3))*KP))}
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)}
G2 4 3 VALUE={STP(((EXP(EX*(LN((V(4,3)/MU)+V(2,3)))))/KC)-((PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)))
+*(((EXP(EX*(LN((V(4,3)/MU)+V(2,3)))))/KC)-((PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,3)/KVB)))}
RCP 1 3 1G ; FOR CONVERGENCE
C1 2 3 {CCG} ; CATHODE-GRID 1
C2 1 2 {CPG1} ; GRID 1-PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
R1 2 5 {RGI} ; FOR GRID CURRENT
D3 5 3 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS