[Rumgucker]

Ich hatte mal vor längerer Zeit ein Spice-Modell für einen (spannungsgesteuerten) Drehko entwickelt. Das sollte mich damals bei den "Parameter"-Diskussionen unterstützen.

Ich vermute und hoffe, dass der damalige Ansatz auch für einen Statik-KH mit Schwabbelmembran (also variable Kapazität) grundsätzlich verwendbar ist.

Schon das damalige Modell enthielt sämtliche Rechnungen für die Anziehungskräfte (die ich als Stromfluss der Spannungssteuerung einprägte). Wenn wir diesen jetzt lediglich eine Federkraft entgegenstellen, dann sollte sich unsere simulierte Membran ganz genauso bewegen wie in der Realität.

Hier das damalige Modell:

.SUBCKT VARICAP 1 2 CTRL
+PARAMS: CMAX=500p DMIN=0.001

* CTRL wobbelt Drehko-C 1:10
* CTRL=1V -> C=500p
* CTRL=0.5V -> C=250p
* CTRL=0.1V -> C=50p

RC 1 3 1m
EC 3 2 Value = { v(int) / limit(v(ctrl),0.1,1) }

GINT 0 INT Value = { I(EC) }
CINT INT 0 {CMAX}

* Flächenberechnung
* A = (C * d) / (eo * er)

* Kraftberechnung (CTRL-Strom [A] entspricht CTRL-Kraft [N])
* F = (eo * er * A * U²) / (2 * d²)
* F = (C * U²) / (2 * d)
* d = DMIN / CTRL , C = CMAX * CTRL
* F = (CMAX * (CTRL * U)²) / (2 * DMIN)

* folgende Zeile auskommentieren, wenn man die Kraftmessung nicht braucht
GCTRL CTRL 0 Value = { CMAX * (v(1,2) * limit(v(ctrl),0.1,1))**2 / (2 * DMIN) }


.ENDS