[Gast]

Nochmals zu den Philips-Modellen der beiden Mosfets:

************************************************
* FAST N-Channel Transistor *
* UCB-3 Parameter Set *
* HIGH-SPEED CMOS Logic Family *
* 10-Jan.-1995 *
************************************************
.Model MHCNEF NMOS
+LEVEL = 3
+KP = 49.6E-6
+VTO = 0.52
+TOX = 49.0E-9
+NSUB = 4.0E15
+GAMMA = 0.74
+PHI = 0.65
+VMAX = 135E3
+RS = 30
+RD = 30
+XJ = 0.10E-6
+LD = 0.69E-6
+DELTA = 0.38
+THETA = 0.048
+ETA = 0.020
+KAPPA = 0.0
+WD = 0.5E-6

***********************************************
* FAST P-Channel transistor *
* UCB-3 Parameter Set *
* HIGH-SPEED CMOS Logic Family *
* 10-Jan.-1995 *
***********************************************
.Model MHCPEF PMOS
+LEVEL = 3
+KP = 24.6E-6
+VTO = -0.51
+TOX = 49.0E-9
+NSUB = 3.6E16
+GAMMA = 0.82
+PHI = 0.65
+VMAX = 600E3
+RS = 60
+RD = 60
+XJ = 0.61E-6
+LD = 0.35E-6
+DELTA = 2.12
+THETA = 0.100
+ETA = 0.260
+KAPPA = 0.0
+WD = 0.5E-6

Als Beispiel sei ein Schmitt-Trigger genommen:

.SUBCKT SMT1F 2 3 50 60
* SCHMITT-TRIGGER INPUT FOR HC14 CMOS INPUT LEVELS
*IN=2, OUT=3, VCC=50, GND=60
R1 2 4 100
MP1 4 50 50 50 MHCPEF W=20U L=2.4U AD=100P AS=100P PD=40U PS=20U
MN1 4 60 60 60 MHCNEF W=35U L=2.4U AD=140P AS=140P PD=50U PS=35U
MP2 5 4 50 50 MHCPEF W=36U L=2.4U AD=140P AS=140P PD=50U PS=35U
MN2 6 4 60 60 MHCNEF W=16U L=2.4U AD= 70P AS= 70P PD=15U PS=17U
MP3 3 4 5 50 MHCPEF W=44U L=2.4U AD=220P AS=220P PD=60U PS=44U
MN3 3 4 6 6 MHCNEF W=17U L=2.4U AD= 70P AS= 70P PD=15U PS=16U
MP4 5 3 60 50 MHCPEF W=36U L=2.4U AD=150P AS=150P PD=60U PS=36U
MN4 6 3 50 6 MHCNEF W= 6U L=4.0U AD= 25P AS= 25P PD=10U PS= 6U
.ENDS

Man erkennt, daß die jeweiligen Gatterbausteine auf die beiden Transistormodelle Bezug nehmen,
oder mit anderen Worten: die beiden Transistormodelle werden tatsächlich simuliert, wobei sie wohl nach Anweisung verändert bzw. der Logik entsprechend verknüpft werden.

Mir kommt das recht realistisch vor, ich würde vorschlagen, ein solches Modell zu testen und zu prüfen, wie es sich in der Simu verhält