[Rumgucker]

Ja.. geht eigentlich ganz simpel, wenn man die Abhängigkeiten erstmal begriffen hat. Soooo schlimm wars dann doch nicht. Zur Erleichterung hab ich mir allerdings Schirmgitter und Anode "entkoppelt".



Das Modell arbeitet nach Telefunken-Datenblatt. Genauer als Duncan. Nur beim g2-Konstantstrombetrieb sieht das Modell etwas pessimistisch aus. Kann aber ja an meiner besonders guten 10?-EL34 liegen

Hier das Modell

Code:

* thanks to Duncan Munro
* and kahlo (kahlo@gmx.de)
* by Rumgucker (www.sodfa.de) September 2008
* for noncommercial use ONLY


.SUBCKT EL34 A S G K
*
* Ia-Ua-Kennlinie festlegen
*
Eat    at    0    VALUE = { 0.636 * ATAN(V(A,K) / 23) }
*
* Anodenstrom ausrechnen
*
Ga         A         K         VALUE = { 1E-3 * PWRS( LIMIT( V(S,K) / 5.7  +  V(G,K)  * 1.8, 0 , 1E6) , 1.5) * V(at) }
*
* Schirmstrom berechnen
*
Gs         S         K    VALUE = { 1.518E-3 * PWRS( LIMIT( V(S,K) / 9.3 + V(G,K) * 0.95 , 0 , 1E6) , 1.5) * (1.1 - V(at)) * LIMIT( V(S,K) , 0 , 10 ) / 10 }
*
* Grid current (approximation - does not model low va/vs)
*
Gg    G    K    VALUE = { PWR( LIMIT( V(G,K) + 1 , 0 , 1E6) , 1.5 ) * 50E-6 }


* Capacitances
Cg1 G K 15.2p
Cak A K 8.4p
Cg1a G A 1.1p

.ENDS